sas信用评分之评分卡的生成
今天介绍的“信用风险评分卡研究”中的生成评分卡的代码,哪一章生成评分卡我琢磨了好久,所以我觉得要是有疑惑的可以看下我写的这篇文章。至于理论的东西我就不说,基本要学评分卡的,这本书都是人手一本啦。
这个代码分为三部分:1、准备数据集。2、代码执行 3、生成sas代码。我今天也会按照这个顺序介绍下。
1 准备数据集。
(1)准备一个逻辑库,最好数据不要太多,可以是本地的也可以是数据库上的。
(2)生成变量码表:
<1>、数值的码表是长这样子的:
其中-1000和-999代表的是空值。Bin是分组,ll是下限,ul是上限。一定要这么 命名,不要问为什么
<2>、字符的码表长这样子:
全部的变量码表的命名都是“new_q_lcc_six_map”,就是后面有个 “_map”的后缀。
(3)准备变量的woe表。在这里强调一下,每个变量都是一张码表还有一张对应的woe表,woe表长下面这样子:
生成表的规则是,第一列是变量码表中的分组,名字是该变量名加上后缀“_b”,第二列就是该分组对应的woe值,命名也是叫woe。Woe值是等下要生成评分的。Woe的命名规则是,该变量名后面加后缀”_woe”。像上面这个数据集,他的数据集名称就叫“new_q_lsix_cnt_woe”。
准备数据集中的工作就这样子啦,强调一遍,这些数据集都必须全部放在我刚才说的那个你准备的逻辑库里面。
2 代码执行
%macro SCScale(BasePoints, BaseOdds, PDO, M_alpha, M_beta);
%local bb;
%let bb=%sysevalf(&PDO / %sysfunc(log(2)));
%let &M_Beta = &bb;
%let &M_alpha= %sysevalf(&BasePoints - &bb * %sysfunc(log(&BaseOdds)));
%mend;
%macro GenSCDS(ParamDS, Lib, DVName, BasePoints, BaseOdds, PDO, SCDS);
%local alpha beta;
%let alpha=;
%let beta=;
%SCScale(&BasePoints, &BaseOdds, &PDO, alpha, beta);
proc transpose data =&ParamDS out=temp_mpt;
run;
%local Intercept;
data temp_mptc;
set temp_mpt;
length VarName $32.;
length MapDS $32.;
length WOEDS $32.;
if _Name_ eq 'Intercept' then do;
call symput('Intercept', compress(&DVName));
delete;
end;
ix=find(upcase(_Name_),'_WOE')-1;
if ix >0 then VarName=substr(_Name_,1,ix);
MapDS=compress(VarName)||'_MAP';
BinName=compress(VarName)||'_b';
WOEDS=_Name_;
Parameter=&DVName;
if _Name_ ne '_LNLIKE_' and &DVName ne . ;
keep VarName BinName MapDS WOEDS Parameter;
run;
%local SCBase;
%let SCBase = %sysfunc(int(&alpha + &beta * &Intercept));
%local i N;
data _null_;
set temp_mptc;
call symput('N',compress(_N_));
run;
%do i=1 %to &N;
%local V_&i P_&i WOE_&i Map_&i;
%end;
data _null_;
set temp_mptc;
call symput('V_'||left(_N_),compress(VarName));
call symput('B_'||left(_N_),compress(BinName));
call symput('P_'||left(_N_),compress(Parameter));
call symput('WOE_'||left(_N_),"&Lib.."||compress(WOEDS));
call symput('Map_'||left(_N_),"&lib.."||compress(MapDS));
run;
%put &&Map_&i.;
proc sql noprint;
create table &SCDS (VarName char(80), UL num, LL num, Points num);
insert into &SCDS values('_BasePoints_' , 0 , 0 , &SCBase);
run; quit;
%do i=1 %to &N;
data temp1;
set &&WOE_&i;
bin=&&B_&i;
VarName="&&V_&i";
ModelParameter=&&P_&i;
run;
proc sort data=temp1;
by bin;
run;
proc contents data=&&Map_&i out=temp_cont nodetails noprint;
run;
%local MapType;
proc sql noprint;
select Type into :MapType from temp_cont where upcase(Name)='CATEGORY';
run; quit;
%if &MapType =1 %then %do;
Data &&Map_&i;
set &&Map_&i;
N_category=Category;
drop category;
run;
%end;
proc sort data=&&Map_&i;
by bin;
run;
data temp_v;
merge temp1 &&Map_&i;
by bin;
run;
proc sort data=temp_v;
by VarName;
run;
proc sort data=&SCDS;
by VarName;
run;
data temp_all;
merge &&SCDS temp_v;
by VarName;
run;
Data &SCDS;
set temp_all;
drop &&B_&i;
run;
%end;
data &SCDS;
set &SCDS;
if VarName = '_BasePoints_' then VarType=0;
else do;
Points=-WOE*ModelParameter * &beta ;
if UL ne . and LL ne . then VarType=1;
else if N_Category eq . then VarType=2;
else VarType=3;
end;
drop WOE bin ModelParameter;
run;
proc sort data=&SCDS;
by VarType VarName;
run;
/*proc datasets library=work nodetails;*/
/*delete temp1 temp_all temp_cont temp_mpt temp_mptc temp_v;*/
/*run; quit;*/
%mend;
%GenSCDS(ParamDS=raw.bb, Lib=raw, DVName=appl_status_1, BasePoints=540, BaseOdds=7.5, PDO=20, SCDS=cc);
代码使用:
%GenSCDS(ParamDS=raw.bb, Lib=raw, DVName=appl_status_1, BasePoints=540, BaseOdds=7.5, PDO=20, SCDS=cc);
ParamDS= 这个数据集就是你执行以下这个过程中outest=产出的数据集,其实就是各个变量的系数。这个说一下(event="1")这个参数,就是假设你的好客户是1的话,那使用这个outest=产出的数据集计算的评分,就是越高分越是好人。
Ods Output ParameterEstimates=aa ;
proc logistic data=test.RONG_total12 outest=bb ;
model APPL_STATUS_1(event="1")=
*****
/selection=s sle=0.05 sls=0.05 include=12;
output out=pp
p=pred_status lower=pi_l upper=pi_u;
run;
Lib=填入你第一步哪里我说的准备的逻辑库。
BasePoints=基础分,具体的基础分是什么,书里有详细的解释。
BaseOdds=7.5 违约比正常,7.5那就是违约率大概是11%。具体看样本的坏样本量。
PDO=20 你想设置的刻度,这个你也自己看书,我不是很能表达这个参数的意义
SCDS=cc 输出数据集。
输出的数据集长的是这样子的:
就是每个变量的区间对应的分数,方便生成sql或者是sas代码去对初始变量执行。
3 生成sas代码
%macro SCSasCode(SCDS,BasePoints, BaseOdds, PDO, IntOpt,FileName);
proc sort data=&SCDS;
by VarType VarName;
run;
data _null_;
set &SCDS nobs=nx;
by VarType VarName;
file "&FileName";
length cond $300.;
length value $300.;
if _N_ =1 then do;
put '/*********************************************/' ;
put '/*********************************************/';
put '/***** Automatically Generated Scorecard *****/';
put '/*********************************************/';
put '/************ SAS CODE ********/';
put;
put '/* Scorecard Scale : */';
put "/* Odds of [ 1 : &BaseOdds ] at [ &BasePoints ] Points ";
put " with PDO of [ &PDO ] */";
put;
put '/*********************************************/';
put '/*********************************************/';
put ;
put '/********** START OF SCORING DATA STEP *******/';
put '/*********************************************/';
put '/*********************************************/';
put;
put 'DATA SCORING;/********** Modify ************/';
put ' SET ScoringDataset; /********** Modify ************/';
put;
put '/*********************************************/';
put '/*********************************************/';
end;
/* print the dataset RulesDS */
%if &IntOpt=1 %then xPoints=int(Points);
%else xPoints=Points; ;
if VarName="_BasePoints_" then do;
put '/*********************************************/';
put "/* Base Points */";
put '/*********************************************/';
put "Points=" xPoints ";";
end;
else do;
if first.VarName then do;
put '/*********************************************/';
put "/* Variable : " VarName " *****/";
put '/*********************************************/';
end;
value= " THEN Points=Points +("||compress(xPoints)||");";
/* The rule */
if VarType=1 then do;/* continuous */
if first.VarName then cond='IF '||compress(VarName)||' LE ('||compress(UL) || ') ';
else if last.VarName then cond='IF '||compress(VarName)||' GT ('|| compress(LL)||')';
else cond='IF '||compress(VarName)||' GT ('|| compress(LL)||') AND '||compress(VarName)||' LE ('||compress(UL) || ') ';
end;
else if VarType=2 then /* nominal string */
cond = 'IF '||compress(VarName)||' = '|| quote(compress(Category)) ;
else /* nominal numeric */
cond='IF '||compress(VarName)||' = ('|| compress(N_Category)||') ';
put " " cond value;
end;
if _N_=Nx then do;
put 'RUN;';
put;
put '/*************END OF SCORING DATA STEP *******/';
put '/*********************************************/';
end;
run;
%mend;
%SCSasCode(SCDS=cc,BasePoints=540, BaseOdds=7.5, PDO=20,IntOpt=1,FileName=D:\工作\简版征信\scorecard.sas);
SCDS=填入你上个代码生成评分卡的那个输出数据集。
BasePoints=如上代码
BaseOdds=如上代码
PDO=如上代码
IntOpt=1的意思就是使所有的分值都四舍五入为整数。
FileName 你想把这个代码放在那里的路径。
数据分析咨询请扫描二维码
CDA数据分析师在中国航信高科技产业园进行了面向测试度量的数据分析培训课程,培训人数近2 ...
2024-05-01CDA数据分析师走进深圳迈瑞生物医疗电子股份有限公司,在迈瑞总部展开了为期两天的培训,本次课程参训人员线上及线下近百人, ...
2024-05-01CDA数据分析师在合肥市对合肥阳光新能源科技有限公司开展了为期8天的企业内训。 合肥阳光新能源科技 ...
2024-05-01CDA数据分析师走进海尔大学,进行了《数据治理与数据中台建设的道与术》专题培训,培训现场爆满,近百人参加了此次培训。 ...
2024-05-01在中国银行苏州分行培训中心开始数据分析师培训,此次培训课程共10天内容,包括Excel、MySQL、概率论与数理统计、SPSS等内容, ...
2024-05-01从实际的业务需求出发,结合行业的典型应用特点,围绕实际的商业问题,探讨数据挖掘、机器学习模型在金融领域的应用,包括获客、信用评分、细分画像、交叉销售、反欺诈、违规识别、时序预测、运筹优化、流程挖掘九个方面,形成 ...
2024-05-01本次培训课程为线上+线下的模式,由于学员编程能力不一、部分学员没有编程基础,故提供统计学、python基 ...
2024-05-01华夏银行信用卡中心-机器学习培训 1、课程亮点 取材于业界一流企业和顶级咨询公司的行业实践;已经被证明是人人 ...
2024-05-01主 题:数据中台建设及数据分析应用主题分享 1. 数据中台市场洞察 2. 主流数据中台产品比较 3. 某企业数据中 ...
2024-05-01围绕“数据驱动”战略,全力打造我行 300 人数字化人才梯队,着力培养数字化管理人才、大数据专业团队 ...
2024-05-01在当今数据驱动的商业环境中,数据分析成为了企业决策的重要依据。通过对大量数据的收集、处理和分析,企业能够更好地理解市场 ...
2024-04-29在人工智能(AI)的世界里,提示词(Prompt)是一种强大的工具,它能够引导AI按照用户的需求产生特定的输出。本文将深入探讨AI ...
2024-04-29CDA立足未来职场,拓展前沿视野——对外经贸大学保险学院举办“三全育人大讲堂”分享行业最新动态。 ...
2024-04-294月2日,CDA数据分析师创始发起人兼协会理事长赵坚毅博士受邀在浙江万里学院举办了一场以“数字化能力在职场中的作用” ...
2024-04-29随机森林(Random Forests)现在机器学习中比较火的一个算法,是一种基于Bagging的集成学习方法,能够很好地处理分类和回归的问 ...
2022-12-23方差分析是数据分析中常用的一种统计分析方法,接下来让我们简单了解一下方差分析的基本思想和原理吧。 方差分析(Analysis ...
2022-12-23来源:关于数据分析与可视化 关于streamlit-aggrid 数据排序 表格样式的调整 数据 ...
2022-08-03作者:麦叔 定义 「把上面晦涩的概念汇成一句话就是:」 ❝ 回调函数就是一个被作为参 ...
2022-08-03现今,高学历人群日益增多,物以稀为贵的高学历光环淡去。无论本科生还是研究生,甚至博士生,求职竞争力都大不如前,就业压力越来越大。
2022-06-01某家企业10个人面试,有9个本科生……如何脱颖而出,除得体的举止和良好的沟通力外,证书成重要筹码,这也是很多人考证的关键所在。
2022-04-14